Nix-Config/flake.nix

{
  description = "Nyx's Nix/Nixos configs";

  inputs = {
    # Nix main stuff
    nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
    nixos-hardware = {
      url = "github:NixOS/nixos-hardware";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nur = { 
      url = "github:nix-community/NUR";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nix-darwin = {
      url = "github:nix-darwin/nix-darwin/nix-darwin-26.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Macos stuff
    nix-homebrew = {
      url = "github:zhaofengli/nix-homebrew";
    };
    homebrew-core = {
      url = "github:homebrew/homebrew-core";
      flake = false;
    };
    homebrew-cask = {
      url = "github:homebrew/homebrew-cask";
      flake = false;
    };
    homebrew-sikarugir = {
      url = "github:Sikarugir-App/homebrew-sikarugir";
      flake = false;
    };

    # Misc
    home-manager = {
      url = "github:nix-community/home-manager/release-26.05";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    steam-config-nix = {
      url = "github:different-name/steam-config-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    hyprland.url = "github:hyprwm/Hyprland";
    hyprland-plugins = {
      url = "github:hyprwm/hyprland-plugins";
      inputs.hyprland.follows = "hyprland";
    };
    split-monitor-workspaces = {
      url = "github:zjeffer/split-monitor-workspaces";
      flake = false;
    };
    nixos-raspberrypi = {
      url = "github:nvmd/nixos-raspberrypi/main";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # secrets
    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    secrets ={
      url = "git+ssh://git@git.nyxerinys.dev:222/nyxerinys/nix-secrets";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, nix-darwin, nixos-raspberrypi, home-manager, ... } @ inputs:
  let
    blades = import ./hosts/servers/blades/systems.nix { inherit inputs; };
  in
  {
    nixosConfigurations = {
      apollo = nixpkgs.lib.nixosSystem {
        modules = [
          ./hosts/base.nix
          ./hosts/apollo
          ./modules/home
          home-manager.nixosModules.home-manager
        ];
        specialArgs = { inherit inputs; };
      };
      iris = nixos-raspberrypi.lib.nixosSystem {
        modules = [
          ./hosts/base.nix
          ./hosts/servers/iris
          nixos-raspberrypi.nixosModules.raspberry-pi-3.base
        ];
        specialArgs = { inherit inputs; };
      };
      poseidon = nixpkgs.lib.nixosSystem {
        modules = [
          ./hosts/base.nix
          ./hosts/servers/poseidon
        ];
        specialArgs = { inherit inputs; };
      };
      dionysus = nixpkgs.lib.nixosSystem {
        modules = [
          ./hosts/base.nix
          ./hosts/servers/dionysus
        ];
        specialArgs = { inherit inputs; };
      };
      nixos = nixpkgs.lib.nixosSystem {
        modules = [
          ./hosts/base.nix
          /etc/nixos/hardware-configuration.nix
        ];
        specialArgs = { inherit inputs; };
      };
    } // 
    blades;
    darwinConfigurations."Artemis" = nix-darwin.lib.darwinSystem {
      modules = [
        # ./hosts/base.nix
        ./hosts/artemis
        ./modules/home
        home-manager.darwinModules.home-manager
      ];
      specialArgs = { inherit inputs; };
    };
  };
}