Rename directory for workflow resources

.github/workflow-resources/PKGBUILD.source

@@ -0,0 +1,46 @@
+# Maintainer: ByteDream
+pkgname=crunchy-cli
+pkgdesc="Command-line downloader for Crunchyroll"
+arch=('x86_64' 'i686' 'arm' 'armv6h' 'armv7h' 'aarch64')
+url="https://github.com/crunchy-labs/crunchy-cli"
+license=('MIT')
+
+pkgver=$CI_PKG_VERSION
+pkgrel=1
+
+depends=('ffmpeg' 'openssl')
+makedepends=('cargo')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/crunchy-labs/crunchy-cli/archive/refs/tags/v${pkgver}.tar.gz")
+sha256sums=('$CI_SHA_SUM')
+# lto causes linking errors when executed by this buildscript. besides, lto is already done by cargo itself (which doesn't cause linking errors)
+options=(!lto)
+
+prepare() {
+  cd "$srcdir/${pkgname}-$pkgver"
+
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_HOME="$srcdir/cargo-home"
+
+  cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+  cd "$srcdir/${pkgname}-$pkgver"
+
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_HOME="$srcdir/cargo-home"
+
+  export CRUNCHY_CLI_GIT_HASH=$CI_GIT_HASH
+  cargo build --frozen --release
+}
+
+package() {
+  cd "$srcdir/${pkgname}-$pkgver"
+
+  install -Dm755 target/release/crunchy-cli $pkgdir/usr/bin/crunchy-cli
+  install -Dm644 target/release/manpages/* -t $pkgdir/usr/share/man/man1
+  install -Dm644 target/release/completions/crunchy-cli.bash $pkgdir/usr/share/bash-completion/completions/crunchy-cli
+  install -Dm644 target/release/completions/_crunchy-cli $pkgdir/usr/share/zsh/site-functions/_crunchy-cli
+  install -Dm644 target/release/completions/crunchy-cli.fish $pkgdir/usr/share/fish/vendor_completions.d/crunchy-cli.fish
+  install -Dm644 LICENSE $pkgdir/usr/share/licenses/crunchy-cli/LICENSE
+}